Familias Ortogonales
Geometría de las ecuaciones diferenciales
1 Algo de geometría con ecuaciones diferenciales
Una familia paramétrica de curvas \(F(x,y,C)=0\) (un parámetro \(C\)) tiene, escondida, una ecuación diferencial: basta con derivar implícitamente y usar la ecuación original para eliminar el parámetro. Lo que queda es una ecuación \(y'=f(x,y)\) que satisface cada curva de la familia — no importa cuál sea el valor de \(C\).
Esto es interesante porque la pendiente \(y'=f(x,y)\) en un punto \((x,y)\) es un dato puramente geométrico. Y si conocemos la pendiente de una familia de curvas en cada punto del plano, también conocemos la pendiente de la familia perpendicular en cada punto: si una recta tiene pendiente \(m\), la perpendicular tiene pendiente \(-1/m\). Entonces:
\[\text{familia original: } y' = f(x,y) \qquad\Longrightarrow\qquad \text{familia ortogonal: } y' = -\frac{1}{f(x,y)}\]
Resolver esta segunda ecuación diferencial da la familia de curvas que cruza a la primera siempre en ángulo recto, en cualquier punto donde se toquen.
Las circunferencias $x^2+y^2=r^2$ (gris) son ortogonales a las rectas $y=mx$ que pasan por el origen (azul claro): el radio y la tangente a la circunferencia siempre son perpendiculares. Mueve los controles y observa el ángulo recto (verde) donde se cruzan.
2 Ejemplo 1 — Trayectorias ortogonales de una familia de parábolas (Ejercicio 1-b)
Esboce la familia \(y = Cx^2\) y encuentre sus trayectorias ortogonales.
Por geometría analítica, cada curva de la familia es una parábola con vértice en el origen: si \(C>0\) abre hacia arriba, si \(C<0\) abre hacia abajo, si \(C=0\) es el eje \(x\), y entre más grande \(|C|\) más rápido crece (más “cerrada” la parábola).
Paso 1 — encontrar la ecuación diferencial de la familia. Derivamos \(y=Cx^2\) implícitamente:
\[y' = 2Cx\]
Esta ecuación todavía tiene el parámetro \(C\); lo eliminamos usando la familia original, \(C = y/x^2\):
\[y' = 2x\cdot\frac{y}{x^2} = \frac{2y}{x}\]
Paso 2 — familia ortogonal. Cambiamos \(y'\) por \(-1/y'\):
\[y' = -\frac{x}{2y}\]
Es de variables separables:
\[2y\,dy = -x\,dx \quad\Longrightarrow\quad y^2 = -\frac{x^2}{2}+C \quad\Longrightarrow\quad x^2+2y^2 = k \qquad (k=2C\geq 0)\]
Es una familia de elipses centradas en el origen, con semieje mayor \(\sqrt{k}\) (en \(x\)) y semieje menor \(\sqrt{k/2}\) (en \(y\)). Lo bonito: la excentricidad no depende de \(k\) — todas las elipses de la familia son semejantes:
\[e = \sqrt{1-\frac{k/2}{k}} = \frac{1}{\sqrt2}\approx 0.707\]
kill(all);
depends(y, x);
/* Familia original y su derivada implícita */
fam: y = C*x^2;
dfam: diff(fam, x); /* diff(y,x) = 2*C*x */
/* Eliminamos C usando la familia original */
Cval: solve(fam, C)[1];
ode_familia: ratsimp(subst(Cval, dfam)); /* diff(y,x) = 2*y/x */
/* Ecuación de la familia ortogonal: y' -> -1/y' */
ode_ortho: 'diff(y,x) = -x/(2*y);
/* Resolvemos (variables separables) */
sol: ode2(ode_ortho, y, x);
/* Excentricidad de la familia de elipses x^2 + 2y^2 = k,
escrita como x^2/k + y^2/(k/2) = 1 */
a2: k; b2: k/2;
e: ratsimp(sqrt(1 - b2/a2)); /* -> 1/sqrt(2), no depende de k */Parábolas de la familia (azul/gris) y elipses de la familia ortogonal (rojo/rosado). El marcador verde muestra el ángulo recto donde la parábola y la elipse seleccionadas se cruzan.
Verifique con GeoGebra que la respuesta es correcta.
3 Ejemplo 2 — Una condición geométrica sobre la normal (Ejercicio 6-b)
Encuentre la familia de curvas tal que la proyección sobre el eje \(x\) del segmento de la normal entre el punto \((x_0,y_0)\) de la curva y el eje \(x\) tiene longitud 1.
Planteamiento. Si la curva satisface \(y'=f(x,y)\), la recta normal en \((x_0,y_0)\) tiene pendiente \(-1/f(x_0,y_0)\) y ecuación
\[y - y_0 = -\frac{1}{f(x_0,y_0)}(x-x_0)\]
Esta recta corta al eje \(x\) (donde \(y=0\)) en el punto \(x_1\) que se despeja de
\[-y_0 = -\frac{1}{f(x_0,y_0)}(x_1-x_0) \quad\Longrightarrow\quad x_1-x_0 = y_0\,f(x_0,y_0)\]
La proyección sobre el eje \(x\) del segmento normal es justamente \(|x_1-x_0| = |y_0\,f(x_0,y_0)|\). Por hipótesis esto vale \(1\), y como \(f(x,y)=y'\):
\[y\,y' = \pm 1\]
Resolviendo: separando variables, \(y\,dy = \pm dx\), así
\[\frac{y^2}{2} = \pm x + C \quad\Longrightarrow\quad y^2 = \pm 2x + C\]
Es una familia de parábolas que abren hacia la derecha o hacia la izquierda.
kill(all);
depends(y, x);
/* La ecuación diferencial de la familia */
ode: y*'diff(y,x) = 1;
sol: ode2(ode, y, x); /* y^2 = 2x + %c */
/* Verificación geométrica: para un punto (x0,y0) sobre y^2 = 2x,
comprobamos que la normal corta al eje x exactamente en x0+1 */
curva: y^2 = 2*x;
pend: rhs(solve(diff(curva, x), diff(y,x))[1]); /* pendiente y' = 1/y en general */
pend0: subst([x=x0, y=sqrt(2*x0)], pend);
pend_normal: -1/pend0;
/* Recta normal: 0 - y0 = pend_normal*(xx - x0), despejamos xx */
y0: sqrt(2*x0);
xx: solve(0 - y0 = pend_normal*(xxvar - x0), xxvar)[1];
ratsimp(rhs(xx) - x0); /* debe dar exactamente 1 */Curva $y^2=2x$ (azul), segmento normal en $(x_0,y_0)$ hasta el eje $x$ (rojo) y su proyección horizontal (verde). Mueve el control: la proyección mide siempre 1, sin importar dónde esté el punto — así es como se construyó la ecuación diferencial.
Página 17–18: 1-a, 1-d, 2, 5, 6-a,d,e,f. 7, 8. Página 49–6. Verifique sus respuestas en Geogebra.